/* Glass cube in povray. 
 * Time-stamp: <2006-06-05 19:26:24 rsmith>
 * Originally made in povray 3.1.
 * Updated to 3.6 on 2006-06-05.
 */

#include "colors.inc"
#include "glass.inc"
#include "stones1.inc"
#include "skies.inc"

global_settings {
  assumed_gamma 2.6
  max_trace_level 5
}

camera {
  location <7, 0.3, -3>*0.9
  look_at  <0, 1, 0>
}

light_source { <-40, 80, -60> color White}

/* Standaard wereld  */

/* bodem */
plane{
  y,-2
  texture{
    pigment{Green*0.8} 
    normal{bumps 0.3}
  }
}

/* voetstuk */
box {
  <-3,-2,-3> <3,0,3>
  texture {
    T_Stone8
  }
}

/* hemel */
sky_sphere{
   S_Cloud2
   rotate y*45
}


/* nu volgen de overige elementen  */

#declare p1= <-1,-1,-1>;
#declare p2= <-1,-1,1>;
#declare p3= <-1,1,-1>;
#declare p4= <-1,1,1>;
#declare p5= <1,-1,-1>;
#declare p6= <1,-1,1>;
#declare p7= <1,1,-1>;
#declare p8= <1,1,1>;
#declare R = 0.25;

union {
  sphere {p1, R}
  sphere {p2, R}
  sphere {p3, R}
  sphere {p4, R}
  sphere {p5, R}
  sphere {p6, R}
  sphere {p7, R}
  sphere {p8, R}
  cylinder {p1,p2,R}
  cylinder {p3,p4,R}
  cylinder {p1,p3,R}
  cylinder {p2,p4,R}
  cylinder {p5,p6,R}
  cylinder {p7,p8,R}
  cylinder {p5,p7,R}
  cylinder {p6,p8,R}
  cylinder {p1,p5,R}
  cylinder {p3,p7,R}
  cylinder {p2,p6,R}
  cylinder {p4,p8,R}

  texture {T_Glass4}
  interior {I_Glass}
  translate <0,1.25,0>
}