/* Persistence of Vision broncode bestand voor de cablehook.
 * Time-stamp: <2006-06-05 21:33:22 rsmith>
 *
 * 2006-06-05: aangepast naar povray 3.6.
 */

#include "colors.inc"
#include "metals.inc"
#include "glass.inc"

global_settings {assumed_gamma 2.2}

background {color White}
light_source {<500,500,500> color White}

camera {
  orthographic
  location <0,0,-150>
//  rotate <0,180,0> //View from Z axis (front)
  rotate <0,180,0> rotate <-30,35,0> // 3D view
//  rotate <-90,0,0> //View from Y axis (top)
  look_at <0,0,0>
}

#declare Formhalf1 = 
difference {
  merge {
    difference {
      box {
        <-40,-40,0>,<40,40,30>
      }
      sphere {
        <0,0,0>, 30
        scale <1,1,0.667>
      }
    }
    box {
      <0,-30,-3>,<-11,30,3>
      rotate <0,120,0>
      translate <12.5,0,9>
    }
    box {
      <0,-30,-3>,<-11,30,3>
      rotate <0,60,0>
      translate <-12.5,0,9>
    }
  }
  merge {
    cylinder {
      <0,-40.01,0>,<0,40.01,0>,7
      translate <12.5,0,9>
    }
    cylinder {
      <0,-40.01,0>,<0,40.01,0>,7
      translate <-12.5,0,9>
    }
  }
};
  
#declare Formhalf2 = 
difference {
  box {
    <-40,-40,0>,<40,40,-30>
  }
  merge {
    box {
      <6,0,0.01>,<-6,40.1,-5>
    }
    cylinder {
      <0,0,0.01>, <0,0,-6>, 25
    }
    cylinder {
      <0,0,0>,<0,0,-36>,6
    }
  }
}

#declare P_Aluminium = 
  color rgb <0.95, 0.95, 0.95>;

#declare F_Milled = 
  finish {
    ambient 0.5
    brilliance 1
    diffuse 0.4
    metallic
    specular 0.15
    roughness 0.5
    reflection 0.01
  };

difference {
  object {
    Formhalf1
  }
  box {
        <-40.1,-40.1,-0.1>,<40.1,0,30.1>
  }
  translate <41,0,0>
  rotate <0,-120,0>
  texture {
    pigment { color rgbf<1.0, 1.0, 1.0, 0.7> }
    finish {
      ambient 0.4
      diffuse 0.1
      reflection 0.1
    }
  }
  interior {I_Glass}
}

difference {
  object {
    Formhalf1
  }
  box {
        <-40.1,0,-0.1>,<40.1,40.1,30.1>
  }
  translate <41,0,0>
  rotate <0,-120,0>
  texture {
    pigment { P_Aluminium }
    finish { F_Milled }
  }
}

cylinder {
  <0,-40.01,0>,<0,40.01,0>,7
  translate <12.5,0,9>
  translate <41,0,0>
  rotate <0,-120,0>
  texture {
    pigment { color rgbf<1.0, 1.0, 1.0, 0.7> }
    finish {
      ambient 0.4
      diffuse 0.1
      reflection 0.1
    }
  }
  interior {I_Glass}
}

cylinder {
  <0,-40.01,0>,<0,40.01,0>,7
  translate <-12.5,0,9>
  translate <41,-45,0>
  rotate <0,-120,0>
  texture {
    pigment { P_Aluminium }
    finish { F_Milled }
  }
}

object {
  Formhalf2
  translate <41,0,0>
  texture {
    pigment { P_Aluminium }
    finish { F_Milled }
  }
}