/* Persistence of Vision broncode bestand voor de cablehook.
 * Time-stamp: <2006-06-05 21:47:26 rsmith>
 *
 * 2006-06-05: updated for povray 3.6.
 */

#include "colors.inc"

global_settings {assumed_gamma 2.2}

background {color White}
light_source {<500,500,250> color White}

camera {
  orthographic
  location <0,0,-100> scale .7
//  rotate <0,180,0> //View from Z axis (front)
  rotate <0,180,0> rotate <-30,45,0> // 3D view
//  rotate <-90,0,0> //View from Y axis (top)
  look_at <0,0,0>
}

#declare messing = texture {
  pigment {color rgb <1 0.9, 0.35>}
  finish {
    ambient 0.5
    diffuse 0.35
    // Highlights
    specular 0.4 metallic
    // Reflected light
    reflection {0.1}
  }
}

#declare Cablehook=
merge {
  difference {
    sphere {
      <0,0,0>, 30
      scale <1,1,0.667>
    }
    merge {
      box {
        <-30.01,-30.01,0.0>,
        <30.01,30.01,-30.01>
      }
      cylinder {
        <0,-30,0>,<0,30,0>,7
        translate <12.5,0,9>
      }
      box {
        <0,-30,-3>,<-11,30,3>
        rotate <0,120,0>
        translate <12.5,0,9>
      }
      cylinder {
        <0,-30,0>,<0,30,0>,7
        translate <-12.5,0,9>
      }
      box {
        <0,-30,-3>,<-11,30,3>
        rotate <0,60,0>
        translate <-12.5,0,9>
      }
    }
  }
  cylinder {
    <0,0,0>, <0,0,-6>, 25
  }
}

object {
  Cablehook
  pigment {
    color rgbt <1, 1, 0.8, 0.5> // transparent
  }
  finish {
    ambient 0.7
    diffuse 0.3
  }
}

merge {
  cylinder {
    <0,0,0>,<0,0,-2>,6
  }
  cylinder {
    <0,0,-2>,<0,0,-4>,2
  }
  cylinder {
    <0,0,-4>,<0,0,-36>,6
  }
  texture {messing}
}