// Time-stamp: <2006-06-06 00:04:32 rsmith>
// Model van een zelfgemaakte injectiepoort.

#include "colors.inc"

//global_settings { assumed_gamma 2.2 }

background {color White}

light_source {
  <1000,1500,1000> White 
  area_light
  <500,0,0>,<0,500,0>,10,10
  circular orient adaptive 1 jitter
  media_attenuation on
}

camera {
  orthographic
  location <100,100,-10> scale 0.37
  look_at <-15,25,0>
}

plane { y, 0  texture {pigment { White } finish {diffuse .4 ambient .8}}}

#declare POM = texture {
	 pigment {color White}
	 finish {specular 0.1 roughness 0.2 ambient 0.7 diffuse 0.3}
}

#declare messing = texture {
  pigment {color rgb <1 0.9, 0.55>}
  finish {
    ambient 0.5
    diffuse 0.35
    // Highlights
    specular 0.3 metallic
    // Reflected light
    reflection {0.04}
  }
}

#declare injpoort = lathe {
	 linear_spline
	 12,
	 <4,0>, <24.5,0>, <25,0.5>, <25,2.5>, 
	 <24.5,3>, <12,5>, <12,14.5>, <11.5,15>, 
	 <6.5,15>, <6.5,5>, <4,5>, <4,0>
}

#declare koppeling = difference {
merge {
      cylinder { <0,7,0>,<0,17,0>,6.48 }
      prism {
      	    linear_spline linear_sweep
	    17, 22,
	    7,
	    <1,0>, <0.5,0.866025>, <-0.5,0.866025>,
	    <-1,0>, <-0.5,-0.866025>, <0.5,-0.866025>, <1,0>
	    scale <8.08290,1,8.08290>
      }
      cylinder { <0,22,0>,<0,24,0>,6.5 }
      prism {
      	    linear_spline linear_sweep
	    24, 36,
	    7,
	    <1,0>, <0.5,0.866025>, <-0.5,0.866025>,
	    <-1,0>, <-0.5,-0.866025>, <0.5,-0.866025>, <1,0>
	    scale <8.08290,1,8.08290>
	    rotate <0,20,0>
      }
}
merge {
      cylinder { <0,35,0>,<0,36.1,0>,5 }
      cylinder { <0,5,0>,<0,35.1,0>,4 }
      lathe {
      	    linear_spline 
	    7, <6.8,36>, <10,36>, <10,32>, <9,32>, <7,34>, <7,35.8>,<6.8,36>
      }
}
}

difference {
	   lathe {injpoort}
	   box {<0,-0.1,0>,<50,60,50>}
	   texture {POM}
}

intersection {
  lathe {injpoort}
  box {<0,-0.1,0>,<50,60,50>}
  hollow // Otherwise media doesn't work!
  texture {
    pigment {color rgbt <1,1,1,1>}
    finish {specular 0.1 roughness 0.2 ambient 0.7 diffuse 0.2}
  }
  interior {
    ior 1
    media {
      scattering {1,0.2}
      // for fast rendering
      //intervals 10
      //samples   10,10
      //method    1
      // for best quality
      //intervals 30
      //samples   10,40
      //method    1
      //variance   0.5/128
      //confidence 0.95
      //aa_level  6
      //aa_threshold 0.03
      //jitter 0.5
    }
  }
}

object {
  koppeling 
  texture {messing}
}